Delphi разработка под Android: App Tethering #3: Передача и получение данных

Продолжаем изучать компоненты App Tethering. В этой статье мы рассмотри способы передачи данных удалённым приложениям.

Список статей:

App Tethering #1: Поиск и подключение к удалённым приложениям
App Tethering #2: Используем удалённые действия (Actions)
App Tethering #3: Передача и получение данных

p.s. Все права на картинку принадлежат Embarcadero Technologies, Inc.

Передача данных.

Существует два способа передачи данных через App Tethering:

Задать постоянный ресурс. Удалённые приложения могут считывать данный ресурс, а также подписываться на обновления этого ресурса.
Передавать данные как временный ресурс. Отправлять можно строки или потоки. Удалённые приложения не могут подписаться на обновления таких ресурсов. Как правило, такой ресурс отправляется единожды.

Теперь давайте рассмотрим оба способа на примере.

Задаём постоянный ресурс.

Чтобы добавить такой ресурс, его нужно поместить в обёртку «TLocalResource». Поддерживаются такие типы данных: Boolean, Integer, Int64, Single, Double, String, TStream.

Шаги:

Дважды щёлкаем по свойству «Resources» у компонента «TTetheringAppProfile»
В открывшемся редакторе, жмём кнопку «Создать», чтобы добавить новый «TLocalResource» в список
Задаём уникальное имя

Теперь ресурс будет доступен удалённым приложениям, они смогут читать его значение и подписываться на обновления ресурса.

После того как мы определили ресурс во время разработки (design time) приложения, мы должны присвоить ему какое-то значение во время выполнения (run time) приложения, сделать это можно так:

TetheringAppProfile1.Resources.FindByName('ResourceName').Value := 'SomeValue';

где,

ResourceName – это уникальное Имя ресурса
SomeValue – это значение, которые мы хотим присвоить ресурсу. Это значение может быть любого из перечисленных выше типов.

Подключенные приложения могут запрашивать значение ресурса. Если приложение подписалось на получение обновлений этого ресурса, то при изменении значения ресурса оно автоматически будет отправлено удалённому приложению.

Передаём данные как временный ресурс.

Для подобной передачи данных предусмотрены методы «SendString» и «SendStream» у компонента «TTetheringAppProfile».

Данные методы должны получить следующие параметры:

<AProfile> - это удалённый профиль, которому мы высылаем временный ресурс
<Description> - строка, описывающая отправляемое значение
<AString> или <AStream> - отправляемое значение, строка, либо поток

Получение данных.

Запрос удалённых ресурсов.

Метод «GetRemoteResourceValue» у компонента «TTetheringAppProfile» позволяет получить значение удалённого ресурса.
Метод «GetRemoteProfileResources» у компонента «TTetheringAppProfile» позволяет получить список доступных ресурсов.

Обработка входящих удалённых ресурсов.

При получении ресурса срабатывают два события «OnAcceptResource» и «OnResourceReceived» у компонента «TTetheringAppProfile» . Для обработки входящих ресурсов необходимо написать обработчики для этих событий.

Получение или отклонение входящего удалённого ресурса.

Вы можете написать обработчик события «OnAcceptResource», чтобы решить, хотите ли вы принимать ресурс или нет.

Чтение входящего удалённого ресурса.

Если вы не обрабатываете событие «OnAcceptResource» или вы не запретили получение ресурса, то сработает событие «OnResourceReceived». Вы можете обрабатывать это событие, чтобы прочитать входящий ресурс.

Подписаться на обновления удалённого ресурса.

Подписаться можно двумя способами:

Указав для ресурса свойство «Kind: Mirror». Тут ситуация такая же как с Действиями в предыдущей статье. Если основной ресурс изменится, то второстепенный ресурс пример такое же значение, при этом сработает событие «TLocalResource.OnResourceReceived» у второстепенного ресурса. При этом приложения должны быть в одной группе и ресурсы должны иметь одинаковые имена.
Подписаться при помощи метода «SubscribeToRemoteItem» у компонента «TTetheringAppProfile».

Я создал простой пример, демонстрирующий работу с постоянным и временным ресурсом.

Все настройки компонентов «TTetheringManager» и «TTetheringAppProfile» стандартны, т.е. как в предыдущих статьях. В каждом проекте добавятся: 1 – TEdit, 1 - TButton

Алгоритм работы этих проектов такой:

Соединяемся
Проект «Client» автоматически подписывается на постоянные ресурс проекта «Server»
Заполняем поле «Edit1» и жмём кнопку, таким образом, мы отправляем текст из «Edit1» как временный ресурс.
Проект «Server» при получении временного ресурса, добавляет его в свой компонент Memo и одновременно изменяет значение своего постоянного ресурса (на любое значение).
Далее, т.к. постоянное значение изменилось, происходит автоматическая отправка этого значения в проект «Client». Получив новое значение, оно будет добавлено в компонент Memo проекта «Client».

Проект «Server»

Структура

Код

procedure TForm2.FormShow(Sender: TObject);
begin
  Label1.Text := 'Local Manager: ' + TMServer.Identifier;
  TMServer.AutoConnect();
end;

procedure TForm2.TAPServerResourceReceived(const Sender: TObject;
  const AResource: TRemoteResource);
begin
  if AResource.ResType = TRemoteResourceType.Data then
  begin
    Memo1.Lines.Add(AResource.Hint + ': ' + AResource.Value.AsString);
    TAPServer.Resources.FindByName('TestSend').Value := '[Server] Постоянный ресурс';
  end;
end;

procedure TForm2.TMServerPairedFromLocal(const Sender: TObject;
  const AManagerInfo: TTetheringManagerInfo);
begin
  Memo1.Lines.Add('PairedFromLocal: ' +
      AManagerInfo.ManagerIdentifier + ' ' +
      AManagerInfo.ManagerText);
end;

procedure TForm2.TMServerPairedToRemote(const Sender: TObject;
  const AManagerInfo: TTetheringManagerInfo);
begin
  Memo1.Lines.Add('PairedToRemote: ' +
      AManagerInfo.ManagerIdentifier + ' ' +
      AManagerInfo.ManagerText);
end;

Проект «Client»

Структура

Код

procedure TForm1.Button1Click(Sender: TObject);
begin
  TAPClient.SendString(TAPClient.ConnectedProfiles[0], '[Client] Временный ресурс', Edit1.Text);
end;

procedure TForm1.FormShow(Sender: TObject);
begin
  Label1.Text := 'Local Manager: ' + TMClient.Identifier;
  TMClient.AutoConnect();
end;

procedure TForm1.TAPClientResources0ResourceReceived(const Sender: TObject;
  const AResource: TRemoteResource);
begin
  Memo1.Lines.Add(AResource.Value.AsString);
end;

procedure TForm1.TMClientPairedFromLocal(const Sender: TObject;
  const AManagerInfo: TTetheringManagerInfo);
begin
  Memo1.Lines.Add('PairedFromLocal: ' +
      AManagerInfo.ManagerIdentifier + ' ' +
      AManagerInfo.ManagerText);
end;

procedure TForm1.TMClientPairedToRemote(const Sender: TObject;
  const AManagerInfo: TTetheringManagerInfo);
begin
  Memo1.Lines.Add('PairedToRemote: ' +
      AManagerInfo.ManagerIdentifier + ' ' +
      AManagerInfo.ManagerText);
end;

Запускаем проекты «Server» и «Client», жмём кнопку и видим результат: